ESP32 SPIFFS: Lưu trữ dữ liệu bền vững khi mất điện

Lưu trữ dữ liệu bền vững trên ESP32 với SPIFFS

Ở bài trước chúng ta mới dừng ở mức đọc 1 file HTML có sẵn trong SPIFFS. Bài này chúng ta sẽ đi xa hơn với ESP32 SPIFFS: cho ESP32 tự ghi dữ liệu mới vào SPIFFS, để dữ liệu đó sống sót qua cả những lần cúp điện hoặc reset board — thứ mà biến thường trong RAM không bao giờ làm được.

Đây là một bài thực hành trong Serie Lập trình ESP32 từ A tới Z.

Tại sao cần lưu dữ liệu bền vững?

Mọi biến khai báo bình thường trong code (int, String…) đều nằm trong RAM — mà RAM thì mất sạch nội dung ngay khi ESP32 mất điện hoặc reset. Với nhiều ứng dụng điều đó không sao, nhưng có những trường hợp bạn cần dữ liệu sống sót qua lần khởi động tiếp theo: số lần thiết bị đã chạy, cấu hình WiFi người dùng nhập vào, log sự kiện gần nhất…

Đây chính xác là ví dụ chiếc điều hòa mình hay nhắc: bạn set 27 độ, tắt điện đi, bật lại điều hòa vẫn nhớ đúng 27 độ chứ không về lại mặc định — vì thông số đó được lưu vào bộ nhớ không mất điện (non-volatile) chứ không phải RAM. SPIFFS trên ESP32 đóng đúng vai trò đó.

Xây dựng bộ đếm lượt truy cập lưu bền vững với ESP32 SPIFFS

Bài này mình làm 1 ví dụ cụ thể dễ kiểm chứng: mỗi lần có người mở trang web, ESP32 tăng bộ đếm lên 1 và ghi ngay xuống file trong SPIFFS. Refresh trang nhiều lần, số đếm tăng dần. Quan trọng hơn: rút nguồn ESP32, cắm lại, số đếm vẫn tiếp tục từ chỗ cũ chứ không nhảy về 0.

Đọc số đếm đã lưu

const char* counterFile = "/counter.txt";

int readCounter() {
  if (!SPIFFS.exists(counterFile)) {
    return 0; // chua co file nghia la chua truy cap lan nao
  }
  File file = SPIFFS.open(counterFile, "r");
  int value = file.parseInt();
  file.close();
  return value;
}
  • SPIFFS.exists() kiểm tra file đã tồn tại chưa — lần chạy đầu tiên chắc chắn chưa có file counter.txt nào cả, lúc đó coi như đếm từ 0.
  • file.parseInt() đọc nội dung file và tự động chuyển thành số nguyên, tiện hơn hẳn so với đọc từng ký tự rồi tự ghép chuỗi.

Ghi số đếm mới xuống file

void writeCounter(int value) {
  File file = SPIFFS.open(counterFile, "w"); // "w" se ghi de toan bo noi dung cu
  file.print(value);
  file.close();
}

Mở file ở chế độ "w" (write) sẽ xóa sạch nội dung cũ rồi ghi giá trị mới vào — khác với "a" (append) là ghi nối thêm vào cuối file. Vì ở đây chỉ cần lưu đúng 1 con số hiện tại, "w" là lựa chọn đúng.

Lưu ý: SPIFFS có tuổi thọ ghi/xóa giới hạn cho mỗi vùng nhớ flash (thường vài chục nghìn đến trăm nghìn lần ghi trên cùng 1 vùng), nên chỉ nên ghi khi dữ liệu thực sự thay đổi, không nên ghi liên tục trong vòng lặp loop() với tần suất cao — ví dụ bài này chỉ ghi khi có người thực sự truy cập trang web, không ghi định kỳ mỗi giây một lần.

Route xử lý web và route reset

void handleRoot() {
  int count = readCounter() + 1;
  writeCounter(count);

  String html = "<h1>So lan truy cap: " + String(count) + "</h1>";
  server.send(200, "text/html", html);
}

void handleReset() {
  writeCounter(0);
  server.sendHeader("Location", "/");
  server.send(303); // redirect ve trang chu sau khi reset
}

Route /reset cho phép đưa bộ đếm về 0 khi cần làm lại từ đầu, dùng mã phản hồi 303 See Other kèm header Location để trình duyệt tự động chuyển hướng về trang chủ ngay sau khi reset — không cần bấm thêm lần nào nữa.

Code đầy đủ

#include <Arduino.h>

#include <WiFi.h>
#include <WebServer.h>
#include <SPIFFS.h>

const char* ssid = "Ten_Wifi_Cua_Ban";
const char* password = "Mat_Khau_Wifi";
const char* counterFile = "/counter.txt";

WebServer server(80);

int readCounter() {
  if (!SPIFFS.exists(counterFile)) {
    return 0;
  }
  File file = SPIFFS.open(counterFile, "r");
  int value = file.parseInt();
  file.close();
  return value;
}

void writeCounter(int value) {
  File file = SPIFFS.open(counterFile, "w");
  file.print(value);
  file.close();
}

void handleRoot() {
  int count = readCounter() + 1;
  writeCounter(count);

  String html = "<!DOCTYPE html><html><head><meta name=\"viewport\" content=\"width=device-width, initial-scale=1\">";
  html += "<style>html { font-family: Helvetica; display: inline-block; margin: 0px auto; text-align: center;} h1{color:Tomato;}</style></head>";
  html += "<body><h1>ESP32 SPIFFS Data Storage</h1>";
  html += "<p>So lan trang nay duoc truy cap: <b>" + String(count) + "</b></p>";
  html += "<p>Thu tat nguon ESP32 roi cap lai, refresh trang - so dem van tiep tuc tang chu khong ve lai 0.</p>";
  html += "</body></html>";

  server.send(200, "text/html", html);
}

void handleReset() {
  writeCounter(0);
  server.sendHeader("Location", "/");
  server.send(303);
}

void setup() {
  Serial.begin(115200);

  if (!SPIFFS.begin(true)) {
    Serial.println("Loi: khong mount duoc SPIFFS");
    return;
  }
  Serial.println("Mount SPIFFS thanh cong");
  Serial.print("So dem hien tai dang luu trong SPIFFS: ");
  Serial.println(readCounter());

  Serial.print("Connecting to wifi ");
  Serial.println(ssid);
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("");
  Serial.println("WiFi connected.");
  Serial.print("IP address: ");
  Serial.println(WiFi.localIP());

  server.on("/", handleRoot);
  server.on("/reset", handleReset);
  server.begin();
  Serial.println("HTTP server da khoi dong");
}

void loop() {
  server.handleClient();
}

Code đầy đủ mình để trên GitHub, các bạn xem tại 03-WebServer/05_SPIFFS_Data_Storage nhé.

Kết quả

Nạp code, mở trình duyệt vào IP của ESP32, refresh vài lần để thấy số đếm tăng dần. Sau đó nhấn nút Reset hoặc rút nguồn ESP32 ra rồi cắm lại, mở lại trang web. Cả 2 cách đều xóa sạch RAM nên đều kiểm chứng được dữ liệu có thật sự nằm trong flash hay không.

Mình truy cập trang 3 lần, reset ESP32 rồi truy cập tiếp (dùng curl trên máy tính thay cho trình duyệt), số đếm đi tiếp từ 3 lên 4 chứ không về 0:

Truy cập webserver ESP32 bằng curl, bộ đếm lưu trong SPIFFS tiếp tục tăng sau khi reset

Log Serial Monitor sau khi reset, ESP32 đọc lại đúng số đếm cũ từ SPIFFS:

Log Serial Monitor: ESP32 SPIFFS mount và đọc lại số đếm đã lưu sau khi reset

Số đếm phải tiếp tục tăng từ giá trị cũ chứ không quay về 0 — đây chính là bằng chứng dữ liệu đã được lưu bền vững trong flash chứ không chỉ nằm trong RAM, đúng không nào. Muốn xóa về 0, truy cập thêm route /reset.

Kết

Kỹ thuật đọc/ghi file trong SPIFFS mở ra rất nhiều ứng dụng thực tế: lưu cấu hình người dùng nhập qua web (SSID, ngưỡng cảnh báo…), ghi log dữ liệu cảm biến theo thời gian, hay đơn giản như bộ đếm ở bài này. Nếu dữ liệu cần lưu chỉ là vài giá trị nhỏ (không phải cả file), các bạn cũng có thể tham khảo thêm thư viện Preferences — dùng vùng nhớ NVS chuyên biệt, phù hợp hơn SPIFFS cho việc lưu cấu hình dạng key-value.

Nếu thấy bài viết có ích, hãy chia sẻ cho bạn bè cùng học. Có thắc mắc gì cứ để lại bình luận, mình sẽ giải đáp nhé!

Rate this post

Để lại một bình luận

Email của bạn sẽ không được hiển thị công khai. Các trường bắt buộc được đánh dấu *